Merge branch 'feature/csdb-v4' into develop

Author: delphidabbler

csdb/v4.16/collection/001.dat

@@ -0,0 +1,8 @@
+function WinFileTimeToDOSFileTime(FT: Windows.TFileTime): Integer;
+begin
+  SysUtils.Win32Check(
+    Windows.FileTimeToDosDateTime(
+      FT, SysUtils.LongRec(Result).Hi, SysUtils.LongRec(Result).Lo
+    )
+  );
+end;

csdb/v4.16/collection/002.dat

@@ -0,0 +1,9 @@
+function WinFileTimeToDateTime(FT: Windows.TFileTime): TDateTime;
+var
+  SysTime: Windows.TSystemTime; // stores date/time in system time format
+begin
+  // Convert file time to system time, raising exception on error
+  SysUtils.Win32Check(Windows.FileTimeToSystemTime(FT, SysTime));
+  // Convert system time to Delphi date time, raising excpetion on error
+  Result := SysUtils.SystemTimeToDateTime(SysTime);
+end;

csdb/v4.16/collection/003.dat

@@ -0,0 +1,4 @@
+function WinFileTimeToStr(FT: Windows.TFileTime): string;
+begin
+  Result := SysUtils.DateTimeToStr(WinFileTimeToDateTime(FT));
+end;

csdb/v4.16/collection/004.dat

@@ -0,0 +1,18 @@
+function ParseDelims(const TextLine: string; var StartPos: Integer;
+  const Delims: string): string;
+var
+  StringEnd: Integer;     // tracks end of current string being parsed out
+begin
+  // Find next non-delimiter char - this is where token starts
+  while (StartPos <= Length(TextLine))
+    and SysUtils.IsDelimiter(Delims, TextLine, StartPos) do
+    Inc(StartPos);
+  // Now find next delimiter - this is where token ends
+  StringEnd := StartPos;
+  while (StringEnd <= Length(TextLine))
+    and not SysUtils.IsDelimiter(Delims, TextLine, StringEnd) do
+    Inc(StringEnd);
+  // Copy result out of string
+  Result := Copy(TextLine, StartPos, StringEnd - StartPos);
+  StartPos := StringEnd + 1;
+end;

csdb/v4.16/collection/005.dat

@@ -0,0 +1,17 @@
+procedure CreateURLShortcut(const ShortcutFile, URL: string);
+var
+  F: TextFile;  // text file
+begin
+  {$I+} // ensure file i/o raises exception on error
+  // Open new file for writing (overwrites any existing file)
+  AssignFile(F, ShortcutFile);
+  Rewrite(F);
+  try
+    // Write file contents: this is simplest basic format of shortcut file
+    WriteLn(F, '[InternetShortcut]');
+    WriteLn(F, 'URL=', URL);
+  finally
+    // Close file
+    CloseFile(F);
+  end;
+end;

csdb/v4.16/collection/006.dat

@@ -0,0 +1,17 @@
+function DeleteFileWithUndo(const FileName: string): Boolean;
+var
+  FOS: ShellAPI.TSHFileOpStruct;  // contains info about required file operation
+begin
+  // Set up structure that determines file operation
+  FillChar(FOS, SizeOf(FOS), 0);
+  with FOS do
+  begin
+    wFunc := ShellAPI.FO_DELETE;      // we're deleting
+    pFrom := PChar(FileName + #0);    // this file (#0#0 terminated)
+    fFlags := ShellAPI.FOF_ALLOWUNDO  // with facility to undo op
+      or ShellAPI.FOF_NOCONFIRMATION  // and we don't want any dialogs
+      or ShellAPI.FOF_SILENT;
+  end;
+  // Perform the operation
+  Result := ShellAPI.SHFileOperation(FOS) = 0;
+end;

csdb/v4.16/collection/007.dat

@@ -0,0 +1,7 @@
+function IsDirectory(const DirName: string): Boolean;
+var
+  Attr: Integer;  // directory's file attributes
+begin
+  Attr := SysUtils.FileGetAttr(DirName);
+  Result := (Attr <> -1) and IsFlagSet(Attr, SysUtils.faDirectory);
+end;

csdb/v4.16/collection/008.dat

@@ -0,0 +1,4 @@
+function DOSToUnixPath(const PathName: string): string;
+begin
+  Result := SysUtils.StringReplace(PathName, '\', '/', [SysUtils.rfReplaceAll]);
+end;

csdb/v4.16/collection/009.dat

@@ -0,0 +1,16 @@
+function GetFileDate(const FName: string): Integer;
+var
+  FileH: Integer;   // file handle
+begin
+  // Open file
+  FileH := SysUtils.FileOpen(FName, SysUtils.fmOpenRead);
+  if FileH = -1 then
+    // Couldn't open file - return -1 to indicate can't get date
+    Result := -1
+  else
+  begin
+    // File opened OK - record date and close file
+    Result := SysUtils.FileGetDate(FileH);
+    SysUtils.FileClose(FileH);
+  end;
+end;

csdb/v4.16/collection/010.dat

@@ -0,0 +1,38 @@
+function GetFixedFileVerInfo(const FileName: string;
+  out FFI: Windows.TVSFixedFileInfo): Boolean;
+var
+  VerInfoBuf: Pointer;    // points to memory storing version info
+  VerInfoSize: Integer;   // size of version info memory
+  Dummy: Cardinal;        // unused parameter required by API function
+  PFFI: Pointer;          // points to fixed file info
+  FFISize: Windows.UINT;  // size of file file info returned from API (unused)
+begin
+  // Assume failure: sets zero result
+  FillChar(FFI, SizeOf(FFI), 0);
+  Result := False;
+  // Get size of version info: there is none if this is zero
+  VerInfoSize := Windows.GetFileVersionInfoSize(PChar(FileName), Dummy);
+  if VerInfoSize > 0 then
+  begin
+    // Allocate memory to store ver info
+    GetMem(VerInfoBuf, VerInfoSize);
+    try
+      // Get the version info, filling buffer
+      if Windows.GetFileVersionInfo(
+        PChar(FileName), Dummy, VerInfoSize, VerInfoBuf
+      ) then
+      begin
+        // Get a pointer to fixed file info
+        if Windows.VerQueryValue(VerInfoBuf, '\', PFFI, FFISize) then
+        begin
+          // Got pointer OK: record file version
+          FFI := Windows.PVSFixedFileInfo(PFFI)^;
+          Result := True;
+        end;
+      end;
+    finally
+      // Dispose of ver info storage
+      FreeMem(VerInfoBuf, VerInfoSize);
+    end;
+  end;
+end;